荔园在线
荔园之美，在春之萌芽，在夏之绽放，在秋之收获，在冬之沉淀
[回到开始]
[上一篇][下一篇]
发信人: eb (恶霸小熊), 信区: Program
标 题: 用VB编写标准CGI程序
发信站: BBS 荔园晨风站 (Sat Jun 27 13:30:02 1998), 转信
用VB编写标准CGI程序
张移山
利用通用网关接口（CGI），Web服务器可以执行一些外部程序，并将这些外部程序所产
生的输出结果和Web服务器所管理的静态文本、图像和声音融合在一起传给相应的Web浏览器
。当客户机的浏览器向Web服务器请求一个HTML文件时，服务器在收到请求后就去寻找这个
文件并将找到的?
募透突Щ６笨突Щ那肭笫且桓鯟GI程序时，Web服务器将激活客户机所请求的
CGI程序并把程序的执行结果传给客户机。
标准的CGI程序是通过环境变量和标准输入输出来与Web服务器交换信息的。任何一个被
系统激活的进程都拥有标准输入和输出这两个文件句柄，CGI程序的进程也不例外。不过，
当CGI程序被Web服务器激活以后，它的标准输入STDIN被连接到Web服务器的标准输出
STDOUT上，而CGI程序的
标准输出STDOUT则被连到服务器的标准输入STDIN上。因此，CGI程序从标准输入读取信息（
也就是从Web服务器的标准输出读信息），而它向标准输出写信息（也就是向Web服务器的标
准输入写信息）。
Web服务器一般将客户机传送来的信息放在它的标准输出和相关环境变量中，而CGI程
序则从环境变量和它的标准输入（也就是Web服务器的标准输出）获取所需的信息，程序的
最终输出结果则被写向它的标准输出STDOUT（也就是Web服务器的标准输入）。Web服务器将
从它的标准输入ST
DIN（也就是CGI程序的标准输出）获取CGI程序的输出结果并将它传送给客户机。客户机、
Web服务器和CGI程序之间的信息交流如下图所示。显然，Web服务器就像是客户机和CGI程序
间的中介。
(G103.JPG)
图 CGI程序和Web浏览器间的信息交流
Web服务器、CGI程序间的这种标准框架在Unix系统下和微软Windows环境中的字符方式
下可以工作得非常好，因为此时系统产生的所有进程都可以存取标准输入和标准输出。但对
于微软Windows图形方式下的程序就不行了，因为它们无法存取标准输入和标准输出。为了
解决这一问题，微
软在Win32系统中创建了另一类型的标准输入和标准输出，程序可以通过调用Win32 API函数
来存取标准输入和标准输出，不过，这就意味着使用这类标准输入和标准输出的CGI程序都
必须是32位的。
微软Windows环境下的其它一些Web服务器（例如Website）则使用另外一种特殊的技术
（即利用INI文件）来实现Web服务器和CGI程序间的数据交流。采用这种被称为“Win-CGI”
规范编写的CGI程序通常只能在部分Web服务器上运行。一般地，支持Win-CGI的Web服务器将
客户端的输入以?
坝泄氐淖刺畔⑿慈氲揭桓鯥NI文件中，而CGI程序则从该INI文件中获取相关信息，这类程
序的执行效率没有标准CGI程序高。
在进行CGI编程时，只要使CGI程序从标准输入和环境变量中获取客户机提供的信息，并
将要传送给客户机的输出结果写入标准输出，剩下的信息传递工作将由Web服务器自动完成
。CGI只是规定了一个标准的接口规范，只要遵守这个标准规范，程序开发人员就可以利用
各种编程工具（如
Perl、C、FORTRAN、Visual Basic等）进行CGI编程了。考虑到Visual Basic的强大的数据
库处理能力、客户机/服务器模式的编程能力以及字符串处理能力，所以本文主要向大家介
绍如何使用VB编写标准的CGI程序。
一、输入输出的处理
一个CGI程序被激活以后，它首先要做的事情就是确定系统平台、Web服务器和客户端浏
览器的状态信息以及客户端用户的输入数据。此外，它还必须能够将相关信息传送给客户端
，否则它将一事无成。这些操作都是通过存取环境变量和标准输入输出来完成的。用VB编写
的CGI程序通过?
饔煤鼸nviron( )来获取相关环境变量的值。存取标准输入输出就要在程序中使用
Win32API函数GetStdHandle( )、ReadFile( )和WriteFile( )，在使用这些函数时首先必须
在程序中声明它们，写声明语句时可以借助于VB提供的API文本查看器。
以下的CGI程序说明了在VB-CGI程序中如何处理环境变量和标准输入输出。该CGI程序非
常简单，可将标准输入中的信息不经任何处理就返回给客户端，它可被任何表单用POST方法
激活：
Declare Function GetStdHandle Lib "kernel32" (ByVal nStdHandle As Long) As
Long
Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As
Any,
ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long,
lpOverlapped As Any) As Long
Declare Function WriteFile Lib "kernel32" (ByVal hFile As Long, ByVal
lpBuffer As String,ByVal nNumberOfBytesToWrite As Long, lpNumberOfBytesWritten
As Long,lpOverlapped As Any) As Long
Public Const STD_INPUT_HANDLE = -10&
Public Const STD_OUTPUT_HANDLE = -11&
Public Const FILE_BEGIN = 0&
Public hStdIn As Long ' 标准输入文件句柄
Public hStdOut As Long ' 标准输出文件句柄
Sub Main()
Dim CGI_ContentLength As String，CGI_QueryString As String
Dim lContentLength As Long ' 标准输入中的字符串的长度
Dim sBuff As String ' 用于存储标准输入中的字符串
Dim lBytesRead As Long ' 实际读入的字符个数
Dim rc As Long
Dim sFormData As String
'调用系统函数生成标准输入输出文件句柄
hStdIn = GetStdHandle(STD_INPUT_HANDLE)
hStdOut = GetStdHandle(STD_OUTPUT_HANDLE)
'获取环境变量CONTENT_LENGTH的值，并将它转换为整型
CGI_ContentLength = Environ("CONTENT_LENGTH")
lContentLength = Val(CGI_ContentLength)
sBuff = String(lContentLength, Chr$(0))
'从标准输入中读数据
rc = ReadFile(hStdIn, ByVal sBuff, lContentLength, lBytesRead, ByVal 0&)
sFormData = Left$(sBuff, lBytesRead)
OutPut "Content-type: text/html" & vbCrLf
OutPut "<HTML><HEAD>"
OutPut "<TITLE>表单传送数据的方法POST </TITLE></HEAD>"
OutPut "<BODY><H3>表单传送数据的方法POST</H3> "
OutPut "<P>本CGI 程序使用Visual Basic编制！ "
OutPut "<P>POST方法传送的数据: "
OutPut "<P>" & sBuff
OutPut "</BODY></HTML>"
End Sub
Sub OutPut(s As String) ' 定义一个向标准输出写信息的函数
Dim lBytesWritten As Long
s = s & vbCrLf
WriteFile hStdOut, s, Len(s), lBytesWritten, ByVal 0&
End Sub
一般地，用VB编译生成的CGI程序不能正确处理中文信息。这主要表现在CGI程序向
STDOUT输出的中文在Web页面上无法正确显示，可通过在该中文字符串后跟着输出一些空格
来解决这个问题。当使用HTML标识符<P>、</P>对Web页面进行排版时，浏览器在显示该Web
页面时会吃掉多余的空
格而只保留一个。在这种情况下，这些空格对Web页面的外观基本上没有什么影响。如果使
用HTML标识符<PRE>、</PRE>对Web页面进行排版，则由于空格不能被浏览器吃掉，所以Web
页面的外观将会受到较大的影响。不过，这时可用HTML的表格<table>、<P>来代替<PRE>对
Web页面进行排版。
注意：整个CGI程序的主体必须放在MAIN()函数中。
二、URL译码与解码
由于Web服务器和浏览器不能正确处理一些特殊的字符，Web服务器和浏览器之间可能会
因此而产生某种程度的误会，所以在数据被传送之前，浏览器都要对表单内客户输入的数据
中的特殊字符进行URL译码。
例如，Web系统用“=”分解表单各元素的NAME和VALUE属性，用“&”分解不同表单元素
的输入数据。如果在表单的输入数据中包含这些特殊的字符，并且表单的数据在传送给Web
服务器前不作任何处理，则Web服务器将无法知道哪一个“=”、“&”是用户输入的，哪一
个是浏览器加上的
。在由表单属性ACTION定义的URL中，也可能会出现一些特殊的字符，当在CGI程序的名称和
路径信息（Path Information）中出现“=”、“&”和“？”时，都会影响数据的正确传送
。
URL译码（URL
Encoding）就是将Web服务器所不能正确处理的特殊字符转换成它的十六进制数的形式，比
如将“%”转换成“%25”、“=”转换成“%3D”等等。这些特殊的字符通常被称作Web系统
的保留字符。在Web系统上无论是用GET方法还是用POST方法传送的数据都要进行URL译码。
CGI程序要想处理表
单传送来的数据，还必须对浏览器URL译码过的数据进行解码。因此，理解URL译码对于我们
进行CGI编程是非常重要的。URL译码一般包括以下步骤：
1、浏览器将所传送的数据根据表单所包含的元素分解成“NAME=VALUE”形式，NAME和
VALUE分别是表单元素的属性。其中，VALUE属性中存储客户机在表单中输入的数据：如果客
户机没有输入数据，则VALUE存储的是表单定义的缺省值；如果缺省值也没有定义，则
VALUE值为空。
2、代表表单中各元素的各个“NAME=VALUE”对被浏览器用“&”连接起来。
3、VALUE属性中存放的数据若含有空格，则被转换成“+”。
4、URL和输入数据中所包含的Web系统的保留字符必须被译码成其十六进制数形式。
5、被译码后的字符被表示成一个“%”和它们的十六进制数形式（即%HH）。
CGI程序从环境变量“QUERY_STRING”或标准输入中读入的数据是经过浏览器URL译码过
的，故在使用这些数据以前还必须对它们进行URL解码。解码的目的是将数据还原成客户端
用户在Web页面上输入时的形式。本文已经介绍了URL译码过程，URL解码过程与它正好相反
，它一般包括以下
步骤：
1、从浏览器用GET或POST方法所传送来的数据中找出代表各个表单元素所储存数据的“
NAME=VALUE”对。
2、VALUE属性中所存放的数据若含有“+”，则被转换成空格。
3、将VALUE属性中所存放的数据的十六进制数“%HH”转换成相应的字符。
Web系统将汉字当成特殊的字符，对它也要进行URL译码。对于一个特殊的单字节字符（
比如“/”），浏览器通常将它译码成十六进制数的形式（比如%2F），“%”表示它后面跟
的是两位十六进制数。当VB程序对其进行处理时调用Chr$函数就可以将其恢复为原貌。而一
个汉字则被浏览?
饕肼氤伤奈皇剖ū热?%D5%C5）。如果CGI程序还像以前那样分别调用Chr(D5)和
Chr(C5)，则由于D5、C5都不是正常的单字节十六进制数码，故Chr函数返回空，汉字将无法
正确还原。正确的做法应该是将有关汉字的四位十六进制数一起传给函数Chr（如
Chr(D5C5)），此时汉字才能?
徽坊乖?
因此，可以让CGI程序对四位连续的十六进制数一起进行译码，以便使汉字能够被正确
还原。但在这种情况下，当客户端用户输入了两个连续的Web系统保留字符时，CGI程序又可
能把它们当成汉字来处理。这时可以让CGI程序在需要对四位连续的十六进制数进行译码时
首先检查前面两位
是否为Web系统的保留字符，如果是则仍然按照单字节的字符处理。不过如果客户端用户在
表单内填写了很多汉字，则CGI程序的负担将会大大加重。事实上，在大多数情况下，客户
端用户很少会使用两个连续的Web系统的保留字符，所以可以只让CGI程序对最容易出现的情
形如“://”（当?
突Ф擞没г诒淼ブ惺淙肽骋籙RL时会出现这种情况）进行检查，本文下节提供的函数
UrlDecode( )可以实现对汉字和Web系统保留字符的URL解码。
三、CGI编程实例
本节将用VB编写一个处理主页客户留言簿的CGI程序。除了要调用本文前面所介绍的
Win32API函数外，程序中还调用了Win32API函数GetTempFileName()来获得一个唯一的临时
文件名。程序中的函数UrlDecode()用来对客户端的输入进行URL译码。函数GetCgiValue()
则用来分解字符串，?
荼淼ピ氐腘AME属性获取其VALUE值，并调用UrlDecode()函数对其进行URL译码。
本程序要求在留言簿文件guests.html中使用一个定位串“<! ENDHEAD >”，将文件的
开始部分和具体的客户留言部分分开。CGI程序将在“<! ENDHEAD >”所在的位置插入客户
新的留言。guests.html应具有如下所示的样式：
<html>
<head><title>DHTML Zone </title></head>
<body bgcolor="#FFFFFF" text="#00000" vlink="#990000" link="#333399">
<! ENDHEAD >
<!---客户的留言部分从这开始-->
<P>……………………….
<!---客户的留言部分结束于此-->
</body></html>
这种样式将保证最后的留言出现在留言簿的最前面。如果要想使最后的留言出现在留言
簿的最后面，则只需将留言簿文件中的定位字符串“<! ENDHEAD >”移到留言簿文件中客户
留言部分和HTML文件结尾部分之间的位置就行了。整个程序的完整代码如下所示：
'guestbook.bas
Declare Function GetStdHandle Lib "kernel32" (ByVal nStdHandle As Long) As
Long
Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As
Any,ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long,
lpOverlapped As Any) As Long
Declare Function WriteFile Lib "kernel32" (ByVal hFile As Long,ByVal
lpBuffer As String, ByVal nNumberOfBytesToWrite As Long,lpNumberOfBytesWritten
As Long, lpOverlapped As Any) As Long
Declare Function GetTempFileName Lib "kernel32" Alias
"GetTempFileNameA"(ByVal lpszPath As String, ByVal lpPrefixString As String,
ByVal wUnique As Long, ByVal lpTempFileName As String) As Long
Public Const STD_INPUT_HANDLE = -10&
Public Const STD_OUTPUT_HANDLE = -11&
Public Const FILE_BEGIN = 0&
Public hStdIn As Long ' 标准输入文件句柄
Public hStdOut As Long ' 标准输出文件句柄
Public sFormData As String ' 用于存储没有经过URL译码的用户输入数据
Public lContentLength As Long
Public CGI_RequestMethod As String
Sub Main()
Dim CGI_ContentLength As String, CGI_QueryString As String, sBuff As String,
chinesetail As String
Dim lBytesRead As Long， rc As Long，I As Long
Dim sEmail As String, sName As String, sURL As String, sfrom As String,
tempstring As String
Dim sComment As String, tempFileName As String, guestbook As String
'CGI程序的初始化工作
hStdIn = GetStdHandle(STD_INPUT_HANDLE)
hStdOut = GetStdHandle(STD_OUTPUT_HANDLE)
CGI_RequestMethod = Environ("REQUEST_METHOD")
CGI_QueryString = Environ("QUERY_STRING")
CGI_ContentLength = Environ("CONTENT_LENGTH")
lContentLength = Val(CGI_ContentLength)
sBuff = String(lContentLength, Chr$(0))
OutPut "Content-type: text/html" & vbCrLf ' 输出MIME类型
OutPut "<FONT SIZE=""+2"">"
If CGI_RequestMethod = "POST" Then
sBuff = String(lContentLength, Chr$(0))
rc = ReadFile(hStdIn, ByVal sBuff, lContentLength, lBytesRead, ByVal 0&)
sFormData = Left$(sBuff, lBytesRead)
ElseIf CGI_RequestMethod = "GET" Then
sFormData = CGI_QueryString
Else
OutPut "Unknow Form Method !"
End If
chinesetail = String(400, " ")
'为了在页面上正确显示中文，生成一个空格串以获取客户端用户的输入
sName = GetCgiValue("name")
sEmail = GetCgiValue("email")
sURL = GetCgiValue("URL")
sfrom = GetCgiValue("from")
sComment = GetCgiValue("URL_Comment")
'对客户端用户的输入进行检查
If Len(sName) = 0 Then
OutPut "<P>非常抱歉！您还没有填写姓名！" & chinesetail
Exit Sub
End If
If Len(sComment) = 0 Then
OutPut "<P>非常抱歉！您还没有提出建议！" & chinesetail
Exit Sub
End If
'获取唯一的临时文件名和留言簿文件并打开它们
tempFileName = TempFile("c:\windows\temp", "gbk")
guestbook = "e:\netscape\server\docs\guests.html"
Open tempFileName For Output As #1
Open guestbook For Input As #2
Do '本循环体用于将留言簿中字符串"<! ENDHEAD >"前面的内容写入临时文件
Line Input #2, tempstring
Print #1, tempstring
Loop While tempstring <> "<! ENDHEAD >" And Not EOF(2)
'向临时文件中插入客户端用户的留言
Print #1, "<hr>" & vbCrLf
Print #1, "<ul>" & vbCrLf
Print #1, "<li><b>留言时间</b>：" & Date$ & " " & Time$ & vbCrLf
Print #1, "<li><b>姓名: </b>" & sName & vbCrLf
If Len(sEmail) <> 0 Then
Print #1, "<li><b>E-mail: </b><a href=""mailto:" & sEmail & """ >" &
sEmail & "</a>" & vbCrLf
End If
If Len(sURL) <> 0 Then
Print #1, "<li><b>我的主页: </b> <a href=""" & sURL & """ >" & sURL & "</a>
" & vbCrLf
End If
If Len(sfrom) <> 0 Then
Print #1, "<li><b>我来自: </b>" & sfrom & vbCrLf
End If
Print #1, "<li><b>我的建议: </b>" & vbCrLf
Print #1, sComment & vbCrLf
Print #1, "</ul>" & vbCrLf
Do '本循环体用于将留言簿剩余的东西写入留言簿
Line Input #2, tempstring
Print #1, tempstring
Loop While Not EOF(2)
Close #1
Close #2
Kill guestbook '删除旧的留言簿
Name tempFileName As guestbook '将临时文件改成新的留言簿
OutPut "<P>非常感谢您的留言!" & chinesetail
OutPut "<P>欢迎您经常光顾本主页！" & chinesetail
OutPut "</FONT>"
End Sub
Sub OutPut(s As String) ' 本子程序用于向标准输出写信息
Dim lBytesWritten As Long
s = s & vbCrLf
WriteFile hStdOut, s, Len(s), lBytesWritten, ByVal 0&
End Sub
Public Function GetCgiValue(cgiName As String) As String
' 本子程序可以获取表单上某一元素的数据
Dim delim2 As Long ' position of "="
Dim delim1 As Long ' position of "&"
Dim n As Integer
Dim pointer1 As Long，pointer2 As Long，length As Long，length1 As Long
Dim tmpstring1 As String，tmpstring2 As String
pointer1 = 1
pointer2 = 1
delim2 = InStr(pointer2, sFormData, "=")
pointer2 = delim2 + 1
Do
length = delim2 - pointer1
tmpstring1 = Mid(sFormData, pointer1, length)
delim1 = InStr(pointer1, sFormData, "&")
pointer1 = delim1 + 1
length1 = delim1 - pointer2
If delim1 = 0 Then length1 = lContentLength + 1 - pointer2
If tmpstring1 = cgiName Then
tmpstring2 = Mid$(sFormData, pointer2, length1)
GetCgiValue = UrlDecode(tmpstring2)
Exit Do
End If
If delim1 = 0 Then
Exit Do
End If
delim2 = InStr(pointer2, sFormData, "=")
pointer2 = delim2 + 1
Loop
End Function
Public Function UrlDecode(ByVal sEncoded As String) As String
' 本函数可以对用户输入的数据进行URL解码
Dim pointer As Long ' sEncoded position pointer
Dim pos As Long ' position of InStr target
Dim temp As String
If sEncoded = "" Then Exit Function
pointer = 1
Do '本循环体用于将"+"转换成空格
pos = InStr(pointer, sEncoded, "+")
If pos = 0 Then Exit Do
Mid$(sEncoded, pos, 1) = " "
pointer = pos + 1
Loop
pointer = 1
Do
'本循环体用于将%XX转换成字符。对于两个连续的%XX，如果第一个%XX不是某些特指的
Web系统保留字符，将把它们转换成汉字
pos = InStr(pointer, sEncoded, "%")
If pos = 0 Then Exit Do
temp = Chr$("&H" & (Mid$(sEncoded, pos + 1, 2)))
If Mid(sEncoded, pos + 3, 1) = "%" And (temp <> ":") And (temp <> "/") _
And (temp <> "(") And (temp <> ")") And (temp <> ".") And (temp <> ",") _
And (temp <> ";") And (temp <> "%") Then
Mid$(sEncoded, pos, 2) = Chr$("&H" & (Mid$(sEncoded, pos + 1, 2)) _
& (Mid$(sEncoded, pos + 4, 2)))
sEncoded = Left$(sEncoded, pos) & Mid$(sEncoded, pos + 6)
pointer = pos + 1
Else
Mid$(sEncoded, pos, 1) = temp
sEncoded = Left$(sEncoded, pos) & Mid$(sEncoded, pos + 3)
pointer = pos + 1
End If
Loop
UrlDecode = sEncoded
Exit Function
End Function
Public Function TempFile(sPath As String, sPrefix As String) As String
'本函数可以获得一个唯一的临时文件名
Dim x As Long，rc As Long
TempFile = String(127, Chr$(0))
rc = GetTempFileName(sPath, sPrefix, ByVal 0&, TempFile)
x = InStr(TempFile, Chr$(0))
If x > 0 Then TempFile = Left$(TempFile, x - 1)
End Function
CGI程序guestbook.bas所要处理的表单如下所示：
<html><head><title>贵宾留言簿</title></head>
<body>
<h3>贵宾留言簿测试</h3>
<form action="/cgi-bin/guest.exe" method="post">
您的姓名: <input type="text" name="name"><br>
您的Email信箱: <input type="text" name="email"><br>
您的主页的URL: <input type="text" name="URL"><br>
您的建议:<br> <textarea name="URL_Comment" rows=4 cols=30></textarea><br>
您来自: <input type="text" name="from"><br>
<input type="submit" value=" 留言 ">
</form>
</body></html>
虽然目前已经有很多可以取代CGI且其性能较CGI要高的技术（例如ASP、ISAPI、NSAPI
等），但使用它们时需要用到专门的知识和工具，并且利用这些技术所编制的程序只适用于
特定的Web服务器或系统平台。考虑到CGI编程具有易用易学性、跨服务器平台特性等优点，
因此，CGI程序还
将在WWW上占有一席之地。
（清华大学22楼603房 张移山 100084）
--
※ 来源:．BBS 荔园晨风站 bbs.szu.edu.cn．[FROM: 192.168.1.168]
[回到开始]
[上一篇][下一篇]
荔园在线首页 友情链接：深圳大学 深大招生 荔园晨风BBS S-Term软件 网络书店